Macaulay2 » Documentation
Packages » ToricHigherDirectImages :: HDI
next | previous | forward | backward | up | index | toc

HDI -- compute the $i$th higher direct image

Description

This method implements Algorithm A.8 in "Reduced \v{C}ech complexes and computing higher direct images under toric maps".

The first Hirzebruch surface $\mathbb{F}_1$ has two geometric interpretations: 1) as the projective bundle $\mathbb{P}(\mathcal{O}_{\mathbb{P}^1} \oplus \mathcal{O}_{\mathbb{P}^1})$ or as the blowup of $\mathbb{P}^2$ at a torus-fixed point. In both cases we get a toric morphism, the projection and blowdown map. In the first case, the (higher) direct images of a line bundle are themselves vector bundles, and hence split.

i1 : X = hirzebruchSurface 1;
i2 : Y = toricProjectiveSpace(1, Variable => y);
i3 : phi = map(Y, X, matrix {{1,0}});

o3 : ToricMap Y <--- X
i4 : D1 = {3,4,0,0};
i5 : RD1 = prune HDI(phi,0,D1)

                 5
o5 = (QQ[y ..y ])
          0   1

o5 : QQ[y ..y ]-module, free, degrees {-3..1}
         0   1
i6 : D2 = toricDivisor({3,-4,0,0},X);

o6 : ToricDivisor on X
i7 : RD2 = prune HDI(phi,1,D2)

                 3
o7 = (QQ[y ..y ])
          0   1

o7 : QQ[y ..y ]-module, free, degrees {-6..-4}
         0   1

In the second case, we can find line bundles whose (higher) direct images which have relations or torsion.

i8 : Z = toricProjectiveSpace(2, Variable => z);
i9 : phi = map(Z, X, matrix {{0,-1},{1,0}});

o9 : ToricMap Z <--- X
i10 : M = (ring X)^{{-6,3}};
i11 : RM = prune phi_*^0 M

                  1
o11 = (QQ[z ..z ])
           0   2

o11 : QQ[z ..z ]-module, free, degrees {3}
          0   2
i12 : L = sheaf_X M;
i13 : RL = prune phi_*^1 L

o13 = cokernel {-8} | z_2 z_0  0    0    0    0   |
               {-8} | 0   -z_2 z_0  0    0    0   |
               {-8} | 0   0    -z_2 z_0  0    0   |
               {-8} | 0   0    0    -z_2 z_0  0   |
               {-8} | 0   0    0    0    -z_2 z_0 |

                                          5
o13 : coherent sheaf on Z, quotient of OO  (8)
                                         Z
i14 : annihilator RL

              5     4   2 3   3 2   4     5
o14 = ideal (z , z z , z z , z z , z z , z )
              2   0 2   0 2   0 2   0 2   0

o14 : Ideal of QQ[z ..z ]
                   0   2

See also

Ways to use HDI:

  • HDI(ToricMap,ZZ,CoherentSheaf)
  • HDI(ToricMap,ZZ,List)
  • HDI(ToricMap,ZZ,Module)
  • HDI(ToricMap,ZZ,ToricDivisor)

For the programmer

The object HDI is a method function.


The source of this document is in /build/reproducible-path/macaulay2-1.25.06+ds/M2/Macaulay2/packages/ToricHigherDirectImages.m2:931:0.